[meta-freescale] [PATCH 0/3] update u-boot-qoriq

[Joris Offouga]

This patch series update u-boot-qoriq for use common file to make easier update
and add u-boot-qoriq-fw-utils

Joris Offouga (3):
Create u-boot-qoriq-common include file
Update recipe for use u-boot-qoriq-common include
Add recipe fw-utils for qoriq

.../u-boot/u-boot-qoriq-common_2018.03.inc | 19 ++++++++
.../u-boot/u-boot-qoriq-fw-utils_2018.03.bb | 45 +++++++++++++++++++
recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb | 19 +-------
3 files changed, 65 insertions(+), 18 deletions(-)
create mode 100644 recipes-bsp/u-boot/u-boot-qoriq-common_2018.03.inc
create mode 100644 recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb

[Joris Offouga]

Use a common file to make easier update, maintain and create
others U-Boot recipes like U-Boot fw-utils

Signed-off-by: Joris Offouga <***@gmail.com>
---
.../u-boot/u-boot-qoriq-common_2018.03.inc | 19 +++++++++++++++++++
1 file changed, 19 insertions(+)
create mode 100644 recipes-bsp/u-boot/u-boot-qoriq-common_2018.03.inc

diff --git a/recipes-bsp/u-boot/u-boot-qoriq-common_2018.03.inc b/recipes-bsp/u-boot/u-boot-qoriq-common_2018.03.inc
new file mode 100644
index 00000000..5be64e49
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-qoriq-common_2018.03.inc
@@ -0,0 +1,19 @@
+
+inherit fsl-u-boot-localversion
+
+LICENSE = "GPLv2 & BSD-3-Clause & BSD-2-Clause & LGPL-2.0 & LGPL-2.1"
+LIC_FILES_CHKSUM = " \
+ file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+ file://Licenses/bsd-2-clause.txt;md5=6a31f076f5773aabd8ff86191ad6fdd5 \
+ file://Licenses/bsd-3-clause.txt;md5=4a1190eac56a9db675d58ebe86eaf50c \
+ file://Licenses/lgpl-2.0.txt;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
+ file://Licenses/lgpl-2.1.txt;md5=4fbd65380cdd255951079008b364516c \
+"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/u-boot;nobranch=1 \
+"
+SRCREV = "1e96fd8f464dfe23eb692a11018c20d70546783b"
+
+S = "${WORKDIR}/git"
+PV_append = "+fslgit"
+LOCALVERSION = "+fsl"
\ No newline at end of file

[Joris Offouga]

Use u-boot-qoriq-common for easier update recipe

Signed-off-by: Joris Offouga <***@gmail.com>
---
recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb | 19 +------------------
1 file changed, 1 insertion(+), 18 deletions(-)

diff --git a/recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb b/recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb
index 48646c03..0ad754f7 100644
--- a/recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb
+++ b/recipes-bsp/u-boot/u-boot-qoriq_2018.03.bb
@@ -1,29 +1,15 @@
require recipes-bsp/u-boot/u-boot.inc
+require u-boot-qoriq-common_${PV}.inc

DESCRIPTION = "U-Boot provided by Freescale with focus on QorIQ boards"
PROVIDES += "u-boot"
-LICENSE = "GPLv2 & BSD-3-Clause & BSD-2-Clause & LGPL-2.0 & LGPL-2.1"
-LIC_FILES_CHKSUM = " \
- file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
- file://Licenses/bsd-2-clause.txt;md5=6a31f076f5773aabd8ff86191ad6fdd5 \
- file://Licenses/bsd-3-clause.txt;md5=4a1190eac56a9db675d58ebe86eaf50c \
- file://Licenses/lgpl-2.0.txt;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
- file://Licenses/lgpl-2.1.txt;md5=4fbd65380cdd255951079008b364516c \
-"

-PV_append = "+fslgit"
INHIBIT_DEFAULT_DEPS = "1"
DEPENDS = "libgcc virtual/${TARGET_PREFIX}gcc"
DEPENDS_append_qoriq-arm64 = " change-file-endianess-native dtc-native tcl-native"
DEPENDS_append_qoriq-arm = " change-file-endianess-native dtc-native tcl-native"
DEPENDS_append_qoriq-ppc = " boot-format-native"

-SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/u-boot;nobranch=1 \
-"
-SRCREV = "1e96fd8f464dfe23eb692a11018c20d70546783b"
-
-S = "${WORKDIR}/git"
-
python () {
if d.getVar("TCMODE", True) == "external-fsl":
return
@@ -61,9 +47,6 @@ WRAP_TARGET_PREFIX ?= "${TARGET_PREFIX}"
EXTRA_OEMAKE = 'CROSS_COMPILE=${WRAP_TARGET_PREFIX} CC="${WRAP_TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS} ${ENDIANNESS_GCC}" LD="${WRAP_TARGET_PREFIX}ld ${ENDIANNESS_LD}" V=1'
EXTRA_OEMAKE += 'HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}"'

-inherit fsl-u-boot-localversion
-LOCALVERSION = "+fsl"
-
do_compile_append_qoriq() {
unset i j k
for config in ${UBOOT_MACHINE}; do

[Joris Offouga]

Initial support for fw utils for qoriq

Signed-off-by: Joris Offouga <***@gmail.com>
---
.../u-boot/u-boot-qoriq-fw-utils_2018.03.bb | 45 +++++++++++++++++++
1 file changed, 45 insertions(+)
create mode 100644 recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb

diff --git a/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb b/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb
new file mode 100644
index 00000000..ae47cb0d
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-qoriq-fw-utils_2018.03.bb
@@ -0,0 +1,45 @@
+require u-boot-qoriq-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+ oe_runmake ${UBOOT_MACHINE}
+ oe_runmake envtools
+}
+
+do_install () {
+ install -d ${D}${base_sbindir}
+ install -d ${D}${sysconfdir}
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+
+ if [ -e ${WORKDIR}/fw_env.config ]; then
+ install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+ else
+ install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+ fi
+}
+
+do_install_class-cross () {
+ install -d ${D}${bindir_cross}
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+ install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+ sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+PROVIDES += "u-boot-fw-utils"
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"